webpac2/trunk/run.pl

#!/usr/bin/perl -w

use strict;

use Cwd qw/abs_path/;
use File::Temp qw/tempdir/;
use Data::Dumper;
use lib './lib';

use WebPAC::Common 0.02;
use WebPAC::Lookup;
use WebPAC::Input 0.03;
use WebPAC::Store 0.03;
use WebPAC::Normalize::XML;
use WebPAC::Normalize::Set;
use WebPAC::Output::TT;
use WebPAC::Validate;
use YAML qw/LoadFile/;
use Getopt::Long;
use File::Path;
use Time::HiRes qw/time/;
use File::Slurp;

=head1 NAME

run.pl - start WebPAC indexing

B<this command will probably go away. Don't get used to it!>

Options:

=over 4

=item --offset 42

start loading (all) databases at offset 42

=item --limit 100

limit loading to 100 records

=item --clean

remove database and Hyper Estraier index before indexing

=item --only=database_name/input_filter

reindex just single database (legacy name is --one)

C</input_filter> is optional part which can be C<name>
or C<type> from input

=item --config conf/config.yml

path to YAML configuration file

=item --force-set

force conversion C<< normalize->path >> in C<config.yml> from
C<.xml> to C<.pl>

=item --stats

disable indexing and dump statistics about field and subfield
usage for each input

=item --validate path/to/validation_file

turn on extra validation of imput records, see L<WebPAC::Validation>

=back

=cut

my $offset;
my $limit;

my $clean = 0;
my $config = 'conf/config.yml';
my $debug = 0;
my $only_filter;
my $force_set = 0;
my $stats = 0;
my $validate_path;

GetOptions(
        "limit=i" => \$limit,
        "offset=i" => \$offset,
        "clean" => \$clean,
        "one=s" => \$only_filter,
        "only=s" => \$only_filter,
        "config" => \$config,
        "debug" => \$debug,
        "force-set" => \$force_set,
        "stats" => \$stats,
        "validate=s" => \$validate_path,
);

$config = LoadFile($config);

print "config = ",Dumper($config) if ($debug);

die "no databases in config file!\n" unless ($config->{databases});

my $log = _new WebPAC::Common()->_get_logger();
$log->info( "-" x 79 );

my $validate;
$validate = new WebPAC::Validate(
        path => $validate_path,
) if ($validate_path);

my $use_indexer = $config->{use_indexer} || 'hyperestraier';
if ($stats) {
        $log->debug("option --stats disables update of indexing engine...");
        $use_indexer = undef;
} else {
        $log->info("using $use_indexer indexing engine...");
}

my $total_rows = 0;
my $start_t = time();

my @links;
my $indexer;

while (my ($database, $db_config) = each %{ $config->{databases} }) {

        my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
        next if ($only_database && $database !~ m/$only_database/i);

        if ($use_indexer) {
                my $indexer_config = $config->{$use_indexer} || $log->logdie("can't find '$use_indexer' part in confguration");
                $indexer_config->{database} = $database;
                $indexer_config->{clean} = $clean;
                $indexer_config->{label} = $db_config->{name};

                if ($use_indexer eq 'hyperestraier') {

                        # open Hyper Estraier database
                        use WebPAC::Output::Estraier '0.10';
                        $indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
                
                } elsif ($use_indexer eq 'kinosearch') {

                        # open KinoSearch
                        use WebPAC::Output::KinoSearch;
                        $indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
                        $indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );

                } else {
                        $log->logdie("unknown use_indexer: $use_indexer");
                }

                $log->logide("can't continue without valid indexer") unless ($indexer);
        }


        #
        # now WebPAC::Store
        #
        my $abs_path = abs_path($0);
        $abs_path =~ s#/[^/]*$#/#;

        my $db_path = $config->{webpac}->{db_path} . '/' . $database;

        if ($clean) {
                $log->info("creating new database '$database' in $db_path");
                rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
        } else {
                $log->info("working on database '$database' in $db_path");
        }

        my $db = new WebPAC::Store(
                path => $db_path,
                database => $database,
                debug => $debug,
        );


        #
        # now, iterate through input formats
        #

        my @inputs;
        if (ref($db_config->{input}) eq 'ARRAY') {
                @inputs = @{ $db_config->{input} };
        } elsif ($db_config->{input}) {
                push @inputs, $db_config->{input};
        } else {
                $log->info("database $database doesn't have inputs defined");
        }

        my @supported_inputs = keys %{ $config->{webpac}->{inputs} };

        foreach my $input (@inputs) {

                next if ($only_input && ($input->{name} !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));

                my $type = lc($input->{type});

                die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));

                my $lookup = new WebPAC::Lookup(
                        lookup_file => $input->{lookup},
                ) if ($input->{lookup});

                my $input_module = $config->{webpac}->{inputs}->{$type};

                $log->info("working on input '$input->{name}' in $input->{path} [type: $input->{type}] using $input_module",
                        $input->{lookup} ? "lookup '$input->{lookup}'" : ""
                );

                my $input_db = new WebPAC::Input(
                        module => $input_module,
                        code_page => $config->{webpac}->{webpac_encoding},
                        limit => $limit || $input->{limit},
                        offset => $offset,
                        lookup => $lookup,
                        recode => $input->{recode},
                        stats => $stats,
                );
                $log->logdie("can't create input using $input_module") unless ($input);

                my $maxmfn = $input_db->open(
                        path => $input->{path},
                        code_page => $input->{encoding},        # database encoding
                        %{ $input },
                );

                my $n = new WebPAC::Normalize::XML(
                #       filter => { 'foo' => sub { shift } },
                        db => $db,
                        lookup_regex => $lookup ? $lookup->regex : undef,
                        lookup => $lookup,
                        prefix => $input->{name},
                );

                my $rules;
                my $normalize_path = $input->{normalize}->{path};

                if ($force_set) {
                        my $new_norm_path = $normalize_path;
                        $new_norm_path =~ s/\.xml$/.pl/;
                        if (-e $new_norm_path) {
                                $log->debug("--force-set replaced $normalize_path with $new_norm_path");
                                $normalize_path = $new_norm_path;
                        } else {
                                $log->debug("--force-set failed on $new_norm_path, fallback to $normalize_path");
                        }
                }

                if ($normalize_path =~ m/\.xml$/i) {
                        $n->open(
                                tag => $input->{normalize}->{tag},
                                xml_file => $normalize_path,
                        );
                } elsif ($normalize_path =~ m/\.(?:yml|yaml)$/i) {
                        $n->open_yaml(
                                path => $normalize_path,
                                tag => $input->{normalize}->{tag},
                        );
                } elsif ($normalize_path =~ m/\.(?:pl)$/i) {
                        $n = undef;
                        $log->info("using WebPAC::Normalize::Set to process $normalize_path");
                        $rules = read_file( $normalize_path ) or die "can't open $normalize_path: $!";
                }

                foreach my $pos ( 0 ... $input_db->size ) {

                        my $row = $input_db->fetch || next;

                        my $mfn = $row->{'000'}->[0];

                        if (! $mfn || $mfn !~ m#^\d+$#) {
                                $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
                                $mfn = $pos;
                                push @{ $row->{'000'} }, $pos;
                        }


                        if ($validate) {
                                my @errors = $validate->validate_errors( $row );
                                $log->error( "MFN $mfn validation errors:\n", join("\n", @errors) ) if (@errors);
                        }

                                
                        my $ds;
                        if ($n) {
                                $ds = $n->data_structure($row);
                        } else {
                                $ds = WebPAC::Normalize::Set::data_structure(
                                        row => $row,
                                        rules => $rules,
                                        lookup => $lookup ? $lookup->lookup_hash : undef,
                                );

                                $db->save_ds(
                                        id => $mfn,
                                        ds => $ds,
                                        prefix => $input->{name},
                                ) if ($ds && !$stats);
                        }

                        $indexer->add(
                                id => $input->{name} . "/" . $mfn,
                                ds => $ds,
                                type => $config->{$use_indexer}->{type},
                        ) if ($indexer);

                        $total_rows++;
                }

                $log->info("statistics of fields usage:\n", $input_db->stats) if ($stats);

        };

        eval { $indexer->finish } if ($indexer && $indexer->can('finish'));

        my $dt = time() - $start_t;
        $log->info("$total_rows records ", $indexer ? "indexed " : "",
                sprintf("in %.2f sec [%.2f rec/sec]",
                        $dt, ($total_rows / $dt)
                )
        );

        #
        # add Hyper Estraier links to other databases
        #
        if (ref($db_config->{links}) eq 'ARRAY') {
                foreach my $link (@{ $db_config->{links} }) {
                        if ($use_indexer eq 'hyperestraier') {
                                $log->info("saving link $database -> $link->{to} [$link->{credit}]");
                                push @links, {
                                        from => $database,
                                        to => $link->{to},
                                        credit => $link->{credit},
                                };
                        } else {
                                $log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
                        }
                }
        }

}

foreach my $link (@links) {
        $log->info("adding link $link->{from} -> $link->{to} [$link->{credit}]");
        $indexer->add_link( %{ $link } );
}
1	#!/usr/bin/perl -w
2
3	use strict;
4
5	use Cwd qw/abs_path/;
6	use File::Temp qw/tempdir/;
7	use Data::Dumper;
8	use lib './lib';
9
10	use WebPAC::Common 0.02;
11	use WebPAC::Lookup;
12	use WebPAC::Input 0.03;
13	use WebPAC::Store 0.03;
14	use WebPAC::Normalize::XML;
15	use WebPAC::Normalize::Set;
16	use WebPAC::Output::TT;
17	use WebPAC::Validate;
18	use YAML qw/LoadFile/;
19	use Getopt::Long;
20	use File::Path;
21	use Time::HiRes qw/time/;
22	use File::Slurp;
23
24	=head1 NAME
25
26	run.pl - start WebPAC indexing
27
28	B<this command will probably go away. Don't get used to it!>
29
30	Options:
31
32	=over 4
33
34	=item --offset 42
35
36	start loading (all) databases at offset 42
37
38	=item --limit 100
39
40	limit loading to 100 records
41
42	=item --clean
43
44	remove database and Hyper Estraier index before indexing
45
46	=item --only=database_name/input_filter
47
48	reindex just single database (legacy name is --one)
49
50	C</input_filter> is optional part which can be C<name>
51	or C<type> from input
52
53	=item --config conf/config.yml
54
55	path to YAML configuration file
56
57	=item --force-set
58
59	force conversion C<< normalize->path >> in C<config.yml> from
60	C<.xml> to C<.pl>
61
62	=item --stats
63
64	disable indexing and dump statistics about field and subfield
65	usage for each input
66
67	=item --validate path/to/validation_file
68
69	turn on extra validation of imput records, see L<WebPAC::Validation>
70
71	=back
72
73	=cut
74
75	my $offset;
76	my $limit;
77
78	my $clean = 0;
79	my $config = 'conf/config.yml';
80	my $debug = 0;
81	my $only_filter;
82	my $force_set = 0;
83	my $stats = 0;
84	my $validate_path;
85
86	GetOptions(
87	"limit=i" => \$limit,
88	"offset=i" => \$offset,
89	"clean" => \$clean,
90	"one=s" => \$only_filter,
91	"only=s" => \$only_filter,
92	"config" => \$config,
93	"debug" => \$debug,
94	"force-set" => \$force_set,
95	"stats" => \$stats,
96	"validate=s" => \$validate_path,
97	);
98
99	$config = LoadFile($config);
100
101	print "config = ",Dumper($config) if ($debug);
102
103	die "no databases in config file!\n" unless ($config->{databases});
104
105	my $log = _new WebPAC::Common()->_get_logger();
106	$log->info( "-" x 79 );
107
108	my $validate;
109	$validate = new WebPAC::Validate(
110	path => $validate_path,
111	) if ($validate_path);
112
113	my $use_indexer = $config->{use_indexer} \|\| 'hyperestraier';
114	if ($stats) {
115	$log->debug("option --stats disables update of indexing engine...");
116	$use_indexer = undef;
117	} else {
118	$log->info("using $use_indexer indexing engine...");
119	}
120
121	my $total_rows = 0;
122	my $start_t = time();
123
124	my @links;
125	my $indexer;
126
127	while (my ($database, $db_config) = each %{ $config->{databases} }) {
128
129	my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
130	next if ($only_database && $database !~ m/$only_database/i);
131
132	if ($use_indexer) {
133	my $indexer_config = $config->{$use_indexer} \|\| $log->logdie("can't find '$use_indexer' part in confguration");
134	$indexer_config->{database} = $database;
135	$indexer_config->{clean} = $clean;
136	$indexer_config->{label} = $db_config->{name};
137
138	if ($use_indexer eq 'hyperestraier') {
139
140	# open Hyper Estraier database
141	use WebPAC::Output::Estraier '0.10';
142	$indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
143
144	} elsif ($use_indexer eq 'kinosearch') {
145
146	# open KinoSearch
147	use WebPAC::Output::KinoSearch;
148	$indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
149	$indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );
150
151	} else {
152	$log->logdie("unknown use_indexer: $use_indexer");
153	}
154
155	$log->logide("can't continue without valid indexer") unless ($indexer);
156	}
157
158
159	#
160	# now WebPAC::Store
161	#
162	my $abs_path = abs_path($0);
163	$abs_path =~ s#/[^/]*$#/#;
164
165	my $db_path = $config->{webpac}->{db_path} . '/' . $database;
166
167	if ($clean) {
168	$log->info("creating new database '$database' in $db_path");
169	rmtree( $db_path ) \|\| $log->warn("can't remove $db_path: $!");
170	} else {
171	$log->info("working on database '$database' in $db_path");
172	}
173
174	my $db = new WebPAC::Store(
175	path => $db_path,
176	database => $database,
177	debug => $debug,
178	);
179
180
181	#
182	# now, iterate through input formats
183	#
184
185	my @inputs;
186	if (ref($db_config->{input}) eq 'ARRAY') {
187	@inputs = @{ $db_config->{input} };
188	} elsif ($db_config->{input}) {
189	push @inputs, $db_config->{input};
190	} else {
191	$log->info("database $database doesn't have inputs defined");
192	}
193
194	my @supported_inputs = keys %{ $config->{webpac}->{inputs} };
195
196	foreach my $input (@inputs) {
197
198	next if ($only_input && ($input->{name} !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));
199
200	my $type = lc($input->{type});
201
202	die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));
203
204	my $lookup = new WebPAC::Lookup(
205	lookup_file => $input->{lookup},
206	) if ($input->{lookup});
207
208	my $input_module = $config->{webpac}->{inputs}->{$type};
209
210	$log->info("working on input '$input->{name}' in $input->{path} [type: $input->{type}] using $input_module",
211	$input->{lookup} ? "lookup '$input->{lookup}'" : ""
212	);
213
214	my $input_db = new WebPAC::Input(
215	module => $input_module,
216	code_page => $config->{webpac}->{webpac_encoding},
217	limit => $limit \|\| $input->{limit},
218	offset => $offset,
219	lookup => $lookup,
220	recode => $input->{recode},
221	stats => $stats,
222	);
223	$log->logdie("can't create input using $input_module") unless ($input);
224
225	my $maxmfn = $input_db->open(
226	path => $input->{path},
227	code_page => $input->{encoding}, # database encoding
228	%{ $input },
229	);
230
231	my $n = new WebPAC::Normalize::XML(
232	# filter => { 'foo' => sub { shift } },
233	db => $db,
234	lookup_regex => $lookup ? $lookup->regex : undef,
235	lookup => $lookup,
236	prefix => $input->{name},
237	);
238
239	my $rules;
240	my $normalize_path = $input->{normalize}->{path};
241
242	if ($force_set) {
243	my $new_norm_path = $normalize_path;
244	$new_norm_path =~ s/\.xml$/.pl/;
245	if (-e $new_norm_path) {
246	$log->debug("--force-set replaced $normalize_path with $new_norm_path");
247	$normalize_path = $new_norm_path;
248	} else {
249	$log->debug("--force-set failed on $new_norm_path, fallback to $normalize_path");
250	}
251	}
252
253	if ($normalize_path =~ m/\.xml$/i) {
254	$n->open(
255	tag => $input->{normalize}->{tag},
256	xml_file => $normalize_path,
257	);
258	} elsif ($normalize_path =~ m/\.(?:yml\|yaml)$/i) {
259	$n->open_yaml(
260	path => $normalize_path,
261	tag => $input->{normalize}->{tag},
262	);
263	} elsif ($normalize_path =~ m/\.(?:pl)$/i) {
264	$n = undef;
265	$log->info("using WebPAC::Normalize::Set to process $normalize_path");
266	$rules = read_file( $normalize_path ) or die "can't open $normalize_path: $!";
267	}
268
269	foreach my $pos ( 0 ... $input_db->size ) {
270
271	my $row = $input_db->fetch \|\| next;
272
273	my $mfn = $row->{'000'}->[0];
274
275	if (! $mfn \|\| $mfn !~ m#^\d+$#) {
276	$log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
277	$mfn = $pos;
278	push @{ $row->{'000'} }, $pos;
279	}
280
281
282	if ($validate) {
283	my @errors = $validate->validate_errors( $row );
284	$log->error( "MFN $mfn validation errors:\n", join("\n", @errors) ) if (@errors);
285	}
286
287
288	my $ds;
289	if ($n) {
290	$ds = $n->data_structure($row);
291	} else {
292	$ds = WebPAC::Normalize::Set::data_structure(
293	row => $row,
294	rules => $rules,
295	lookup => $lookup ? $lookup->lookup_hash : undef,
296	);
297
298	$db->save_ds(
299	id => $mfn,
300	ds => $ds,
301	prefix => $input->{name},
302	) if ($ds && !$stats);
303	}
304
305	$indexer->add(
306	id => $input->{name} . "/" . $mfn,
307	ds => $ds,
308	type => $config->{$use_indexer}->{type},
309	) if ($indexer);
310
311	$total_rows++;
312	}
313
314	$log->info("statistics of fields usage:\n", $input_db->stats) if ($stats);
315
316	};
317
318	eval { $indexer->finish } if ($indexer && $indexer->can('finish'));
319
320	my $dt = time() - $start_t;
321	$log->info("$total_rows records ", $indexer ? "indexed " : "",
322	sprintf("in %.2f sec [%.2f rec/sec]",
323	$dt, ($total_rows / $dt)
324	)
325	);
326
327	#
328	# add Hyper Estraier links to other databases
329	#
330	if (ref($db_config->{links}) eq 'ARRAY') {
331	foreach my $link (@{ $db_config->{links} }) {
332	if ($use_indexer eq 'hyperestraier') {
333	$log->info("saving link $database -> $link->{to} [$link->{credit}]");
334	push @links, {
335	from => $database,
336	to => $link->{to},
337	credit => $link->{credit},
338	};
339	} else {
340	$log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
341	}
342	}
343	}
344
345	}
346
347	foreach my $link (@links) {
348	$log->info("adding link $link->{from} -> $link->{to} [$link->{credit}]");
349	$indexer->add_link( %{ $link } );
350	}