WebPAC/Output/Estraier.pm

package WebPAC::Output::Estraier;

use warnings;
use strict;

use base qw/WebPAC::Common/;

use HyperEstraier;
use Text::Iconv;
use Data::Dumper;
use LWP::Simple;
use URI::Escape;

=head1 NAME

WebPAC::Output::Estraier - Create Hyper Estraier full text index

=head1 VERSION

Version 0.02

=cut

our $VERSION = '0.02';

=head1 SYNOPSIS

Create full text index using Hyper Estraier index from data with
type C<search>.

=head1 FUNCTIONS

=head2 new

Connect to Hyper Estraier index using HTTP

 my $est = new WebPAC::Output::Estraier(
        masterurl => 'http://localhost:1978/',
        user => 'admin',
        passwd => 'admin',
        database => 'demo',
        encoding => 'iso-8859-2',
 );

Options are:

=over 4

=item masterurl

URI to C<estmaster> node

=item user

C<estmaster> user with sufficient rights

=item passwd

password for user

=item database

name of database from which data comes

=item encoding

character encoding of C<data_structure> if it's differenet than C<ISO-8859-2>
(and it probably is). This encoding will be converted to C<UTF-8> for
Hyper Estraier.

=back

Name of database will be used to form URI of documents in index.

=cut

sub new {
        my $class = shift;
        my $self = {@_};
        bless($self, $class);

        my $log = $self->_get_logger;

        $log->debug("self: ", sub { Dumper($self) });

        foreach my $p (qw/masterurl user passwd database/) {
                $log->logdie("need $p") unless ($self->{$p});
        }

        my $url = $self->{masterurl} . '/node/' . $self->{database};
        $url =~ s#//#/#g;
        $self->{url} = $url;

        $log->info("opening Hyper Estraier index $self->{url}");

        my @nodes = $self->est_master( action => 'nodelist' );

        if (! grep(/$self->{database}/, @nodes)) {
                $log->info("creating index $url");
                $self->est_master(
                        action => 'nodeadd',
                        name => $self->{database},
                        label => "WebPAC $self->{database}",
                ) || $log->logdie("can't create Hyper Estraier node $self->{database}");
        }

        $self->{'db'} = HyperEstraier::Node->new($self->{url});
        $self->{'db'}->set_auth($self->{'user'}, $self->{passwd});

        my $encoding = $self->{'encoding'} || 'ISO-8859-2';
        $log->info("using encoding $encoding");

        $self->{'iconv'} = new Text::Iconv($encoding, 'UTF-8') or
                $log->logdie("can't create conversion from $encoding to UTF-8");

        $self ? return $self : return undef;
}


=head2 add

Adds one entry to database.

  $est->add(
        id => 42,
        ds => $ds,
        type => 'display',
        url_prefix => 'database name',
        text => 'optional text from which snippet is created',
  );

This function will create  entries in index using following URI format:

  C<file:///database%20name/000>

Each tag in C<data_structure> with specified C<type> will create one
attribute and corresponding hidden text (used for search).

=cut

sub add {
        my $self = shift;

        my $args = {@_};

        my $log = $self->_get_logger;

        my $database = $self->{'database'} || $log->logconfess('no database in $self');
        $log->logconfess('need db in object') unless ($self->{'db'});

        foreach my $p (qw/id ds type/) {
                $log->logdie("need $p") unless ($args->{$p});
        }

        my $type = $args->{'type'};
        my $mfn = $args->{'id'};

        my $uri = "file:///$type/$database/$mfn";
        $log->debug("creating $uri");

        my $doc = HyperEstraier::Document->new;
        $doc->add_attr('@uri', $self->{'iconv'}->convert($uri) );

        $log->debug("ds = ", sub { Dumper($args->{'ds'}) } );

        # filter all tags which have type defined
        my @tags = grep {
                ref($args->{'ds'}->{$_}) eq 'HASH' && defined( $args->{'ds'}->{$_}->{$type} )
        } keys %{ $args->{'ds'} };

        $log->debug("tags = ", join(",", @tags));

        return unless (@tags);

        foreach my $tag (@tags) {

                my $vals = join(" ", @{ $args->{'ds'}->{$tag}->{$type} });

                $log->logconfess("no values for $tag/$type") unless ($vals);

                $vals = $self->{'iconv'}->convert( $vals ) or
                        $log->logdie("can't convert '$vals' to UTF-8");

                $doc->add_attr( $tag, $vals );
                $doc->add_hidden_text( $vals );
        }

        my $text = $args->{'text'};
        if ( $text ) {
                $text = $self->{'iconv'}->convert( $text ) or
                        $log->logdie("can't convert '$text' to UTF-8");
                $doc->add_text( $text );
        }

        $log->debug("adding ", sub { $doc->dump_draft } );
        $self->{'db'}->put_doc($doc) || $log->logdie("can't add document $uri to index");

        return 1;
}

=head2 est_master

Issue administrative commands to C<estmaster> process and receive response
as array of lines

  my $nodelist = $self->est_master( action => nodelist );

=cut

my $estmaster_actions = {
        userdel => [ qw/name/ ],
        nodelist => [],
        nodeadd => [ qw/name label/ ],
        nodedel => [ qw/name/ ],
};

sub est_master {
        my $self = shift;
        my $args = {@_};
        my $log = $self->_get_logger;

        $log->debug(Dumper($args));

        my $action = $args->{action} || $log->logconfess("no action specified");

        $log->logdie("action '$action' isn't supported") unless ($estmaster_actions->{$action});

        my $url = $self->{masterurl} . '/master?action=' . $action;

        foreach my $arg (@{ $estmaster_actions->{$action} }) {
                $log->logdie("missing parametar $arg for action $action") unless ($args->{$arg});
                $url .= '&' . $arg . '=' . uri_escape( $args->{$arg} );
        }

        $log->debug("calling $url");

        my $tsv = get($url);

        if (! $tsv) {
                $log->warn("unable to call $url");
                return;
        }

        return split(/\n/, $tsv);
}

=head1 AUTHOR

Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>

=head1 COPYRIGHT & LICENSE

Copyright 2005 Dobrica Pavlinusic, All Rights Reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut

1; # End of WebPAC::Output::Estraier
1	dpavlin	1	package WebPAC::Output::Estraier;
2
3			use warnings;
4			use strict;
5
6	dpavlin	74	use base qw/WebPAC::Common/;
7
8			use HyperEstraier;
9			use Text::Iconv;
10			use Data::Dumper;
11	dpavlin	210	use LWP::Simple;
12			use URI::Escape;
13	dpavlin	74
14	dpavlin	1	=head1 NAME
15
16	dpavlin	74	WebPAC::Output::Estraier - Create Hyper Estraier full text index
17	dpavlin	1
18			=head1 VERSION
19
20	dpavlin	210	Version 0.02
21	dpavlin	1
22			=cut
23
24	dpavlin	210	our $VERSION = '0.02';
25	dpavlin	1
26			=head1 SYNOPSIS
27
28	dpavlin	74	Create full text index using Hyper Estraier index from data with
29			type C<search>.
30	dpavlin	1
31	dpavlin	74	=head1 FUNCTIONS
32	dpavlin	1
33	dpavlin	74	=head2 new
34	dpavlin	1
35	dpavlin	74	Connect to Hyper Estraier index using HTTP
36	dpavlin	1
37	dpavlin	74	my $est = new WebPAC::Output::Estraier(
38	dpavlin	210	masterurl => 'http://localhost:1978/',
39	dpavlin	74	user => 'admin',
40			passwd => 'admin',
41			database => 'demo',
42			encoding => 'iso-8859-2',
43			);
44	dpavlin	1
45	dpavlin	74	Options are:
46	dpavlin	1
47	dpavlin	74	=over 4
48	dpavlin	1
49	dpavlin	210	=item masterurl
50	dpavlin	1
51	dpavlin	74	URI to C<estmaster> node
52
53			=item user
54
55			C<estmaster> user with sufficient rights
56
57			=item passwd
58
59			password for user
60
61			=item database
62
63			name of database from which data comes
64
65			=item encoding
66
67			character encoding of C<data_structure> if it's differenet than C<ISO-8859-2>
68			(and it probably is). This encoding will be converted to C<UTF-8> for
69			Hyper Estraier.
70
71			=back
72
73			Name of database will be used to form URI of documents in index.
74
75	dpavlin	1	=cut
76
77	dpavlin	74	sub new {
78			my $class = shift;
79			my $self = {@_};
80			bless($self, $class);
81
82			my $log = $self->_get_logger;
83
84	dpavlin	210	$log->debug("self: ", sub { Dumper($self) });
85
86			foreach my $p (qw/masterurl user passwd database/) {
87	dpavlin	74	$log->logdie("need $p") unless ($self->{$p});
88			}
89
90	dpavlin	210	my $url = $self->{masterurl} . '/node/' . $self->{database};
91			$url =~ s#//#/#g;
92			$self->{url} = $url;
93	dpavlin	74
94	dpavlin	210	$log->info("opening Hyper Estraier index $self->{url}");
95	dpavlin	74
96	dpavlin	210	my @nodes = $self->est_master( action => 'nodelist' );
97
98			if (! grep(/$self->{database}/, @nodes)) {
99			$log->info("creating index $url");
100			$self->est_master(
101			action => 'nodeadd',
102			name => $self->{database},
103			label => "WebPAC $self->{database}",
104			) \|\| $log->logdie("can't create Hyper Estraier node $self->{database}");
105			}
106
107			$self->{'db'} = HyperEstraier::Node->new($self->{url});
108			$self->{'db'}->set_auth($self->{'user'}, $self->{passwd});
109
110	dpavlin	74	my $encoding = $self->{'encoding'} \|\| 'ISO-8859-2';
111			$log->info("using encoding $encoding");
112
113	dpavlin	75	$self->{'iconv'} = new Text::Iconv($encoding, 'UTF-8') or
114	dpavlin	85	$log->logdie("can't create conversion from $encoding to UTF-8");
115	dpavlin	74
116			$self ? return $self : return undef;
117	dpavlin	1	}
118
119	dpavlin	75
120	dpavlin	74	=head2 add
121	dpavlin	1
122	dpavlin	74	Adds one entry to database.
123
124			$est->add(
125			id => 42,
126			ds => $ds,
127			type => 'display',
128			url_prefix => 'database name',
129			text => 'optional text from which snippet is created',
130			);
131
132			This function will create entries in index using following URI format:
133
134			C<file:///database%20name/000>
135
136			Each tag in C<data_structure> with specified C<type> will create one
137			attribute and corresponding hidden text (used for search).
138
139	dpavlin	1	=cut
140
141	dpavlin	74	sub add {
142			my $self = shift;
143
144			my $args = {@_};
145
146			my $log = $self->_get_logger;
147
148			my $database = $self->{'database'} \|\| $log->logconfess('no database in $self');
149			$log->logconfess('need db in object') unless ($self->{'db'});
150
151			foreach my $p (qw/id ds type/) {
152			$log->logdie("need $p") unless ($args->{$p});
153			}
154
155			my $type = $args->{'type'};
156			my $mfn = $args->{'id'};
157
158			my $uri = "file:///$type/$database/$mfn";
159			$log->debug("creating $uri");
160
161			my $doc = HyperEstraier::Document->new;
162	dpavlin	75	$doc->add_attr('@uri', $self->{'iconv'}->convert($uri) );
163	dpavlin	74
164			$log->debug("ds = ", sub { Dumper($args->{'ds'}) } );
165
166			# filter all tags which have type defined
167			my @tags = grep {
168	dpavlin	113	ref($args->{'ds'}->{$_}) eq 'HASH' && defined( $args->{'ds'}->{$_}->{$type} )
169	dpavlin	74	} keys %{ $args->{'ds'} };
170
171			$log->debug("tags = ", join(",", @tags));
172
173			return unless (@tags);
174
175			foreach my $tag (@tags) {
176
177			my $vals = join(" ", @{ $args->{'ds'}->{$tag}->{$type} });
178
179			$log->logconfess("no values for $tag/$type") unless ($vals);
180
181	dpavlin	75	$vals = $self->{'iconv'}->convert( $vals ) or
182	dpavlin	85	$log->logdie("can't convert '$vals' to UTF-8");
183	dpavlin	75
184			$doc->add_attr( $tag, $vals );
185			$doc->add_hidden_text( $vals );
186	dpavlin	74	}
187
188			my $text = $args->{'text'};
189	dpavlin	75	if ( $text ) {
190			$text = $self->{'iconv'}->convert( $text ) or
191	dpavlin	85	$log->logdie("can't convert '$text' to UTF-8");
192	dpavlin	75	$doc->add_text( $text );
193			}
194	dpavlin	74
195			$log->debug("adding ", sub { $doc->dump_draft } );
196	dpavlin	85	$self->{'db'}->put_doc($doc) \|\| $log->logdie("can't add document $uri to index");
197	dpavlin	74
198			return 1;
199	dpavlin	1	}
200
201	dpavlin	210	=head2 est_master
202
203			Issue administrative commands to C<estmaster> process and receive response
204			as array of lines
205
206			my $nodelist = $self->est_master( action => nodelist );
207
208			=cut
209
210			my $estmaster_actions = {
211			userdel => [ qw/name/ ],
212			nodelist => [],
213			nodeadd => [ qw/name label/ ],
214			nodedel => [ qw/name/ ],
215			};
216
217			sub est_master {
218			my $self = shift;
219			my $args = {@_};
220			my $log = $self->_get_logger;
221
222			$log->debug(Dumper($args));
223
224			my $action = $args->{action} \|\| $log->logconfess("no action specified");
225
226			$log->logdie("action '$action' isn't supported") unless ($estmaster_actions->{$action});
227
228			my $url = $self->{masterurl} . '/master?action=' . $action;
229
230			foreach my $arg (@{ $estmaster_actions->{$action} }) {
231			$log->logdie("missing parametar $arg for action $action") unless ($args->{$arg});
232			$url .= '&' . $arg . '=' . uri_escape( $args->{$arg} );
233			}
234
235			$log->debug("calling $url");
236
237			my $tsv = get($url);
238
239			if (! $tsv) {
240			$log->warn("unable to call $url");
241			return;
242			}
243
244			return split(/\n/, $tsv);
245			}
246
247	dpavlin	1	=head1 AUTHOR
248
249			Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
250
251			=head1 COPYRIGHT & LICENSE
252
253			Copyright 2005 Dobrica Pavlinusic, All Rights Reserved.
254
255			This program is free software; you can redistribute it and/or modify it
256			under the same terms as Perl itself.
257
258			=cut
259
260			1; # End of WebPAC::Output::Estraier