| 1 |
package WebPAC::Input; |
| 2 |
|
| 3 |
use warnings; |
| 4 |
use strict; |
| 5 |
|
| 6 |
use blib; |
| 7 |
|
| 8 |
use WebPAC::Common; |
| 9 |
use base qw/WebPAC::Common/; |
| 10 |
use Data::Dump qw/dump/; |
| 11 |
use Encode qw/from_to/; |
| 12 |
|
| 13 |
=head1 NAME |
| 14 |
|
| 15 |
WebPAC::Input - read different file formats into WebPAC |
| 16 |
|
| 17 |
=head1 VERSION |
| 18 |
|
| 19 |
Version 0.17 |
| 20 |
|
| 21 |
=cut |
| 22 |
|
| 23 |
our $VERSION = '0.17'; |
| 24 |
|
| 25 |
=head1 SYNOPSIS |
| 26 |
|
| 27 |
This module implements input as database which have fixed and known |
| 28 |
I<size> while indexing and single unique numeric identifier for database |
| 29 |
position ranging from 1 to I<size>. |
| 30 |
|
| 31 |
Simply, something that is indexed by unmber from 1 .. I<size>. |
| 32 |
|
| 33 |
Examples of such databases are CDS/ISIS files, MARC files, lines in |
| 34 |
text file, and so on. |
| 35 |
|
| 36 |
Specific file formats are implemented using low-level interface modules, |
| 37 |
located in C<WebPAC::Input::*> namespace which export C<open_db>, |
| 38 |
C<fetch_rec> and optional C<init> functions. |
| 39 |
|
| 40 |
Perhaps a little code snippet. |
| 41 |
|
| 42 |
use WebPAC::Input; |
| 43 |
|
| 44 |
my $db = WebPAC::Input->new( |
| 45 |
module => 'WebPAC::Input::ISIS', |
| 46 |
); |
| 47 |
|
| 48 |
$db->open( path => '/path/to/database' ); |
| 49 |
print "database size: ",$db->size,"\n"; |
| 50 |
while (my $rec = $db->fetch) { |
| 51 |
# do something with $rec |
| 52 |
} |
| 53 |
|
| 54 |
|
| 55 |
|
| 56 |
=head1 FUNCTIONS |
| 57 |
|
| 58 |
=head2 new |
| 59 |
|
| 60 |
Create new input database object. |
| 61 |
|
| 62 |
my $db = new WebPAC::Input( |
| 63 |
module => 'WebPAC::Input::MARC', |
| 64 |
encoding => 'ISO-8859-2', |
| 65 |
recode => 'char pairs', |
| 66 |
no_progress_bar => 1, |
| 67 |
); |
| 68 |
|
| 69 |
C<module> is low-level file format module. See L<WebPAC::Input::ISIS> and |
| 70 |
L<WebPAC::Input::MARC>. |
| 71 |
|
| 72 |
Optional parametar C<encoding> specify application code page (which will be |
| 73 |
used internally). This should probably be your terminal encoding, and by |
| 74 |
default, it C<ISO-8859-2>. |
| 75 |
|
| 76 |
C<recode> is optional string constisting of character or words pairs that |
| 77 |
should be replaced in input stream. |
| 78 |
|
| 79 |
C<no_progress_bar> disables progress bar output on C<STDOUT> |
| 80 |
|
| 81 |
This function will also call low-level C<init> if it exists with same |
| 82 |
parametars. |
| 83 |
|
| 84 |
=cut |
| 85 |
|
| 86 |
sub new { |
| 87 |
my $class = shift; |
| 88 |
my $self = {@_}; |
| 89 |
bless($self, $class); |
| 90 |
|
| 91 |
my $log = $self->_get_logger; |
| 92 |
|
| 93 |
$log->logconfess("code_page argument is not suppored any more. change it to encoding") if ($self->{lookup}); |
| 94 |
$log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_ref") if ($self->{lookup}); |
| 95 |
$log->logconfess("low_mem argument is not suppored any more. rewrite it to load_row and save_row") if ($self->{low_mem}); |
| 96 |
|
| 97 |
$log->logconfess("specify low-level file format module") unless ($self->{module}); |
| 98 |
my $module_path = $self->{module}; |
| 99 |
$module_path =~ s#::#/#g; |
| 100 |
$module_path .= '.pm'; |
| 101 |
$log->debug("require low-level module $self->{module} from $module_path"); |
| 102 |
|
| 103 |
require $module_path; |
| 104 |
|
| 105 |
$self->{'encoding'} ||= 'ISO-8859-2'; |
| 106 |
|
| 107 |
$self ? return $self : return undef; |
| 108 |
} |
| 109 |
|
| 110 |
=head2 open |
| 111 |
|
| 112 |
This function will read whole database in memory and produce lookups. |
| 113 |
|
| 114 |
my $store; # simple in-memory hash |
| 115 |
|
| 116 |
$input->open( |
| 117 |
path => '/path/to/database/file', |
| 118 |
code_page => 'cp852', |
| 119 |
limit => 500, |
| 120 |
offset => 6000, |
| 121 |
stats => 1, |
| 122 |
lookup_coderef => sub { |
| 123 |
my $rec = shift; |
| 124 |
# store lookups |
| 125 |
}, |
| 126 |
modify_records => { |
| 127 |
900 => { '^a' => { ' : ' => '^b' } }, |
| 128 |
901 => { '*' => { '^b' => ' ; ' } }, |
| 129 |
}, |
| 130 |
modify_file => 'conf/modify/mapping.map', |
| 131 |
save_row => sub { |
| 132 |
my $a = shift; |
| 133 |
$store->{ $a->{id} } = $a->{row}; |
| 134 |
}, |
| 135 |
load_row => sub { |
| 136 |
my $a = shift; |
| 137 |
return defined($store->{ $a->{id} }) && |
| 138 |
$store->{ $a->{id} }; |
| 139 |
}, |
| 140 |
|
| 141 |
); |
| 142 |
|
| 143 |
By default, C<code_page> is assumed to be C<cp852>. |
| 144 |
|
| 145 |
C<offset> is optional parametar to position at some offset before reading from database. |
| 146 |
|
| 147 |
C<limit> is optional parametar to read just C<limit> records from database |
| 148 |
|
| 149 |
C<stats> create optional report about usage of fields and subfields |
| 150 |
|
| 151 |
C<lookup_coderef> is closure to called to save data into lookups |
| 152 |
|
| 153 |
C<modify_records> specify mapping from subfields to delimiters or from |
| 154 |
delimiters to subfields, as well as oprations on fields (if subfield is |
| 155 |
defined as C<*>. |
| 156 |
|
| 157 |
C<modify_file> is alternative for C<modify_records> above which preserves order and offers |
| 158 |
(hopefully) simplier sintax than YAML or perl (see L</modify_file_regex>). This option |
| 159 |
overrides C<modify_records> if both exists for same input. |
| 160 |
|
| 161 |
C<save_row> and C<load_row> are low-level implementation of store engine. Calling convention |
| 162 |
is documented in example above. |
| 163 |
|
| 164 |
Returns size of database, regardless of C<offset> and C<limit> |
| 165 |
parametars, see also C<size>. |
| 166 |
|
| 167 |
=cut |
| 168 |
|
| 169 |
sub open { |
| 170 |
my $self = shift; |
| 171 |
my $arg = {@_}; |
| 172 |
|
| 173 |
my $log = $self->_get_logger(); |
| 174 |
|
| 175 |
$log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_coderef") if ($arg->{lookup}); |
| 176 |
$log->logconfess("lookup_coderef must be CODE, not ",ref($arg->{lookup_coderef})) |
| 177 |
if ($arg->{lookup_coderef} && ref($arg->{lookup_coderef}) ne 'CODE'); |
| 178 |
|
| 179 |
$log->debug( $arg->{lookup_coderef} ? '' : 'not ', "using lookup_coderef"); |
| 180 |
|
| 181 |
$log->logcroak("need path") if (! $arg->{'path'}); |
| 182 |
my $code_page = $arg->{'code_page'} || 'cp852'; |
| 183 |
|
| 184 |
# store data in object |
| 185 |
$self->{'input_code_page'} = $code_page; |
| 186 |
foreach my $v (qw/path offset limit/) { |
| 187 |
$self->{$v} = $arg->{$v} if ($arg->{$v}); |
| 188 |
} |
| 189 |
|
| 190 |
if ($arg->{load_row} || $arg->{save_row}) { |
| 191 |
$log->logconfess("save_row and load_row must be defined in pair and be CODE") unless ( |
| 192 |
ref($arg->{load_row}) eq 'CODE' && |
| 193 |
ref($arg->{save_row}) eq 'CODE' |
| 194 |
); |
| 195 |
$self->{load_row} = $arg->{load_row}; |
| 196 |
$self->{save_row} = $arg->{save_row}; |
| 197 |
$log->debug("using load_row and save_row instead of in-memory hash"); |
| 198 |
} |
| 199 |
|
| 200 |
my $filter_ref; |
| 201 |
my $recode_regex; |
| 202 |
my $recode_map; |
| 203 |
|
| 204 |
if ($self->{recode}) { |
| 205 |
my @r = split(/\s/, $self->{recode}); |
| 206 |
if ($#r % 2 != 1) { |
| 207 |
$log->logwarn("recode needs even number of elements (some number of valid pairs)"); |
| 208 |
} else { |
| 209 |
while (@r) { |
| 210 |
my $from = shift @r; |
| 211 |
my $to = shift @r; |
| 212 |
$recode_map->{$from} = $to; |
| 213 |
} |
| 214 |
|
| 215 |
$recode_regex = join '|' => keys %{ $recode_map }; |
| 216 |
|
| 217 |
$log->debug("using recode regex: $recode_regex"); |
| 218 |
} |
| 219 |
|
| 220 |
} |
| 221 |
|
| 222 |
my $rec_regex; |
| 223 |
if (my $p = $arg->{modify_file}) { |
| 224 |
$log->debug("using modify_file $p"); |
| 225 |
$rec_regex = $self->modify_file_regexps( $p ); |
| 226 |
} elsif (my $h = $arg->{modify_records}) { |
| 227 |
$log->debug("using modify_records ", sub { dump( $h ) }); |
| 228 |
$rec_regex = $self->modify_record_regexps(%{ $h }); |
| 229 |
} |
| 230 |
$log->debug("rec_regex: ", sub { dump($rec_regex) }) if ($rec_regex); |
| 231 |
|
| 232 |
my $class = $self->{module} || $log->logconfess("can't get low-level module name!"); |
| 233 |
|
| 234 |
my $ll_db = $class->new( |
| 235 |
path => $arg->{path}, |
| 236 |
# filter => sub { |
| 237 |
# my ($l,$f_nr) = @_; |
| 238 |
# return unless defined($l); |
| 239 |
# from_to($l, $code_page, $self->{'encoding'}); |
| 240 |
# $l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map); |
| 241 |
# return $l; |
| 242 |
# }, |
| 243 |
%{ $arg }, |
| 244 |
); |
| 245 |
|
| 246 |
unless (defined($ll_db)) { |
| 247 |
$log->logwarn("can't open database $arg->{path}, skipping..."); |
| 248 |
return; |
| 249 |
} |
| 250 |
|
| 251 |
my $size = $ll_db->size; |
| 252 |
|
| 253 |
unless ($size) { |
| 254 |
$log->logwarn("no records in database $arg->{path}, skipping..."); |
| 255 |
return; |
| 256 |
} |
| 257 |
|
| 258 |
my $from_rec = 1; |
| 259 |
my $to_rec = $size; |
| 260 |
|
| 261 |
if (my $s = $self->{offset}) { |
| 262 |
$log->debug("skipping to MFN $s"); |
| 263 |
$from_rec = $s; |
| 264 |
} else { |
| 265 |
$self->{offset} = $from_rec; |
| 266 |
} |
| 267 |
|
| 268 |
if ($self->{limit}) { |
| 269 |
$log->debug("limiting to ",$self->{limit}," records"); |
| 270 |
$to_rec = $from_rec + $self->{limit} - 1; |
| 271 |
$to_rec = $size if ($to_rec > $size); |
| 272 |
} |
| 273 |
|
| 274 |
# store size for later |
| 275 |
$self->{size} = ($to_rec - $from_rec) ? ($to_rec - $from_rec + 1) : 0; |
| 276 |
|
| 277 |
$log->info("processing $self->{size}/$size records [$from_rec-$to_rec] convert $code_page -> $self->{encoding}", $self->{stats} ? ' [stats]' : ''); |
| 278 |
|
| 279 |
# read database |
| 280 |
for (my $pos = $from_rec; $pos <= $to_rec; $pos++) { |
| 281 |
|
| 282 |
$log->debug("position: $pos\n"); |
| 283 |
|
| 284 |
my $rec = $ll_db->fetch_rec($pos, sub { |
| 285 |
my ($l,$f_nr,$debug) = @_; |
| 286 |
# return unless defined($l); |
| 287 |
# return $l unless ($rec_regex && $f_nr); |
| 288 |
|
| 289 |
return unless ( defined($l) && defined($f_nr) ); |
| 290 |
|
| 291 |
warn "-=> $f_nr ## |$l|\n" if ($debug); |
| 292 |
$log->debug("-=> $f_nr ## $l"); |
| 293 |
|
| 294 |
# codepage conversion and recode_regex |
| 295 |
from_to($l, $code_page, $self->{'encoding'}); |
| 296 |
$l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map); |
| 297 |
|
| 298 |
# apply regexps |
| 299 |
if ($rec_regex && defined($rec_regex->{$f_nr})) { |
| 300 |
$log->logconfess("regexps->{$f_nr} must be ARRAY") if (ref($rec_regex->{$f_nr}) ne 'ARRAY'); |
| 301 |
my $c = 0; |
| 302 |
foreach my $r (@{ $rec_regex->{$f_nr} }) { |
| 303 |
my $old_l = $l; |
| 304 |
$log->logconfess("expected regex in ", dump( $r )) unless defined($r->{regex}); |
| 305 |
eval '$l =~ ' . $r->{regex}; |
| 306 |
if ($old_l ne $l) { |
| 307 |
my $d = "|$old_l| -> |$l| "; # . $r->{regex}; |
| 308 |
$d .= ' +' . $r->{line} . ' ' . $r->{file} if defined($r->{line}); |
| 309 |
$d .= ' ' . $r->{debug} if defined($r->{debug}); |
| 310 |
$log->debug("MODIFY $d"); |
| 311 |
warn "*** $d\n" if ($debug); |
| 312 |
|
| 313 |
} |
| 314 |
$log->error("error applying regex: $r") if ($@); |
| 315 |
} |
| 316 |
} |
| 317 |
|
| 318 |
$log->debug("<=- $f_nr ## |$l|"); |
| 319 |
warn "<=- $f_nr ## $l\n" if ($debug); |
| 320 |
return $l; |
| 321 |
}); |
| 322 |
|
| 323 |
$log->debug(sub { dump($rec) }); |
| 324 |
|
| 325 |
if (! $rec) { |
| 326 |
$log->warn("record $pos empty? skipping..."); |
| 327 |
next; |
| 328 |
} |
| 329 |
|
| 330 |
# store |
| 331 |
if ($self->{save_row}) { |
| 332 |
$self->{save_row}->({ |
| 333 |
id => $pos, |
| 334 |
row => $rec, |
| 335 |
}); |
| 336 |
} else { |
| 337 |
$self->{data}->{$pos} = $rec; |
| 338 |
} |
| 339 |
|
| 340 |
# create lookup |
| 341 |
$arg->{'lookup_coderef'}->( $rec ) if ($rec && $arg->{'lookup_coderef'}); |
| 342 |
|
| 343 |
# update counters for statistics |
| 344 |
if ($self->{stats}) { |
| 345 |
|
| 346 |
# fetch clean record with regexpes applied for statistics |
| 347 |
my $rec = $ll_db->fetch_rec($pos); |
| 348 |
|
| 349 |
foreach my $fld (keys %{ $rec }) { |
| 350 |
$self->{_stats}->{fld}->{ $fld }++; |
| 351 |
|
| 352 |
$log->logdie("invalid record fild $fld, not ARRAY") |
| 353 |
unless (ref($rec->{ $fld }) eq 'ARRAY'); |
| 354 |
|
| 355 |
foreach my $row (@{ $rec->{$fld} }) { |
| 356 |
|
| 357 |
if (ref($row) eq 'HASH') { |
| 358 |
|
| 359 |
foreach my $sf (keys %{ $row }) { |
| 360 |
next if ($sf eq 'subfields'); |
| 361 |
$self->{_stats}->{sf}->{ $fld }->{ $sf }->{count}++; |
| 362 |
$self->{_stats}->{sf}->{ $fld }->{ $sf }->{repeatable}++ |
| 363 |
if (ref($row->{$sf}) eq 'ARRAY'); |
| 364 |
} |
| 365 |
|
| 366 |
} else { |
| 367 |
$self->{_stats}->{repeatable}->{ $fld }++; |
| 368 |
} |
| 369 |
} |
| 370 |
} |
| 371 |
} |
| 372 |
|
| 373 |
$self->progress_bar($pos,$to_rec) unless ($self->{no_progress_bar}); |
| 374 |
|
| 375 |
} |
| 376 |
|
| 377 |
$self->{pos} = -1; |
| 378 |
$self->{last_pcnt} = 0; |
| 379 |
|
| 380 |
# store max mfn and return it. |
| 381 |
$self->{max_pos} = $to_rec; |
| 382 |
$log->debug("max_pos: $to_rec"); |
| 383 |
|
| 384 |
# save for dump |
| 385 |
$self->{ll_db} = $ll_db; |
| 386 |
|
| 387 |
return $size; |
| 388 |
} |
| 389 |
|
| 390 |
=head2 fetch |
| 391 |
|
| 392 |
Fetch next record from database. It will also displays progress bar. |
| 393 |
|
| 394 |
my $rec = $isis->fetch; |
| 395 |
|
| 396 |
Record from this function should probably go to C<data_structure> for |
| 397 |
normalisation. |
| 398 |
|
| 399 |
=cut |
| 400 |
|
| 401 |
sub fetch { |
| 402 |
my $self = shift; |
| 403 |
|
| 404 |
my $log = $self->_get_logger(); |
| 405 |
|
| 406 |
$log->logconfess("it seems that you didn't load database!") unless ($self->{pos}); |
| 407 |
|
| 408 |
if ($self->{pos} == -1) { |
| 409 |
$self->{pos} = $self->{offset}; |
| 410 |
} else { |
| 411 |
$self->{pos}++; |
| 412 |
} |
| 413 |
|
| 414 |
my $mfn = $self->{pos}; |
| 415 |
|
| 416 |
if ($mfn > $self->{max_pos}) { |
| 417 |
$self->{pos} = $self->{max_pos}; |
| 418 |
$log->debug("at EOF"); |
| 419 |
return; |
| 420 |
} |
| 421 |
|
| 422 |
$self->progress_bar($mfn,$self->{max_pos}) unless ($self->{no_progress_bar}); |
| 423 |
|
| 424 |
my $rec; |
| 425 |
|
| 426 |
if ($self->{load_row}) { |
| 427 |
$rec = $self->{load_row}->({ id => $mfn }); |
| 428 |
} else { |
| 429 |
$rec = $self->{data}->{$mfn}; |
| 430 |
} |
| 431 |
|
| 432 |
$rec ||= 0E0; |
| 433 |
} |
| 434 |
|
| 435 |
=head2 pos |
| 436 |
|
| 437 |
Returns current record number (MFN). |
| 438 |
|
| 439 |
print $isis->pos; |
| 440 |
|
| 441 |
First record in database has position 1. |
| 442 |
|
| 443 |
=cut |
| 444 |
|
| 445 |
sub pos { |
| 446 |
my $self = shift; |
| 447 |
return $self->{pos}; |
| 448 |
} |
| 449 |
|
| 450 |
|
| 451 |
=head2 size |
| 452 |
|
| 453 |
Returns number of records in database |
| 454 |
|
| 455 |
print $isis->size; |
| 456 |
|
| 457 |
Result from this function can be used to loop through all records |
| 458 |
|
| 459 |
foreach my $mfn ( 1 ... $isis->size ) { ... } |
| 460 |
|
| 461 |
because it takes into account C<offset> and C<limit>. |
| 462 |
|
| 463 |
=cut |
| 464 |
|
| 465 |
sub size { |
| 466 |
my $self = shift; |
| 467 |
return $self->{size}; |
| 468 |
} |
| 469 |
|
| 470 |
=head2 seek |
| 471 |
|
| 472 |
Seek to specified MFN in file. |
| 473 |
|
| 474 |
$isis->seek(42); |
| 475 |
|
| 476 |
First record in database has position 1. |
| 477 |
|
| 478 |
=cut |
| 479 |
|
| 480 |
sub seek { |
| 481 |
my $self = shift; |
| 482 |
my $pos = shift; |
| 483 |
|
| 484 |
my $log = $self->_get_logger(); |
| 485 |
|
| 486 |
$log->logconfess("called without pos") unless defined($pos); |
| 487 |
|
| 488 |
if ($pos < 1) { |
| 489 |
$log->warn("seek before first record"); |
| 490 |
$pos = 1; |
| 491 |
} elsif ($pos > $self->{max_pos}) { |
| 492 |
$log->warn("seek beyond last record"); |
| 493 |
$pos = $self->{max_pos}; |
| 494 |
} |
| 495 |
|
| 496 |
return $self->{pos} = (($pos - 1) || -1); |
| 497 |
} |
| 498 |
|
| 499 |
=head2 stats |
| 500 |
|
| 501 |
Dump statistics about field and subfield usage |
| 502 |
|
| 503 |
print $input->stats; |
| 504 |
|
| 505 |
=cut |
| 506 |
|
| 507 |
sub stats { |
| 508 |
my $self = shift; |
| 509 |
|
| 510 |
my $log = $self->_get_logger(); |
| 511 |
|
| 512 |
my $s = $self->{_stats}; |
| 513 |
if (! $s) { |
| 514 |
$log->warn("called stats, but there is no statistics collected"); |
| 515 |
return; |
| 516 |
} |
| 517 |
|
| 518 |
my $max_fld = 0; |
| 519 |
|
| 520 |
my $out = join("\n", |
| 521 |
map { |
| 522 |
my $f = $_ || die "no field"; |
| 523 |
my $v = $s->{fld}->{$f} || die "no s->{fld}->{$f}"; |
| 524 |
$max_fld = $v if ($v > $max_fld); |
| 525 |
|
| 526 |
my $o = sprintf("%4s %d ~", $f, $v); |
| 527 |
|
| 528 |
if (defined($s->{sf}->{$f})) { |
| 529 |
map { |
| 530 |
$o .= sprintf(" %s:%d%s", $_, |
| 531 |
$s->{sf}->{$f}->{$_}->{count}, |
| 532 |
$s->{sf}->{$f}->{$_}->{repeatable} ? '*' : '', |
| 533 |
); |
| 534 |
} sort keys %{ $s->{sf}->{$f} }; |
| 535 |
} |
| 536 |
|
| 537 |
if (my $v_r = $s->{repeatable}->{$f}) { |
| 538 |
$o .= " ($v_r)" if ($v_r != $v); |
| 539 |
} |
| 540 |
|
| 541 |
$o; |
| 542 |
} sort { $a cmp $b } keys %{ $s->{fld} } |
| 543 |
); |
| 544 |
|
| 545 |
$log->debug( sub { dump($s) } ); |
| 546 |
|
| 547 |
return $out; |
| 548 |
} |
| 549 |
|
| 550 |
=head2 dump_ascii |
| 551 |
|
| 552 |
Display humanly readable dump of record |
| 553 |
|
| 554 |
=cut |
| 555 |
|
| 556 |
sub dump_ascii { |
| 557 |
my $self = shift; |
| 558 |
|
| 559 |
return unless $self->{ll_db}; |
| 560 |
|
| 561 |
if ($self->{ll_db}->can('dump_rec')) { |
| 562 |
return $self->{ll_db}->dump_ascii( $self->{pos} ); |
| 563 |
} else { |
| 564 |
return dump( $self->{ll_db}->fetch_rec( $self->{pos} ) ); |
| 565 |
} |
| 566 |
} |
| 567 |
|
| 568 |
=head2 modify_record_regexps |
| 569 |
|
| 570 |
Generate hash with regexpes to be applied using L<filter>. |
| 571 |
|
| 572 |
my $regexpes = $input->modify_record_regexps( |
| 573 |
900 => { '^a' => { ' : ' => '^b' } }, |
| 574 |
901 => { '*' => { '^b' => ' ; ' } }, |
| 575 |
); |
| 576 |
|
| 577 |
=cut |
| 578 |
|
| 579 |
sub _get_regex { |
| 580 |
my ($sf,$from,$to) = @_; |
| 581 |
|
| 582 |
# protect / |
| 583 |
$from =~ s!/!\\/!gs; |
| 584 |
$to =~ s!/!\\/!gs; |
| 585 |
|
| 586 |
if ($from =~ m/^regex:(.+)$/) { |
| 587 |
$from = $1; |
| 588 |
} else { |
| 589 |
$from = '\Q' . $from . '\E'; |
| 590 |
} |
| 591 |
if ($sf =~ /^\^/) { |
| 592 |
return |
| 593 |
's/\Q'. $sf .'\E([^\^]*?)'. $from .'([^\^]*?)/'. $sf .'$1'. $to .'$2/'; |
| 594 |
} else { |
| 595 |
return |
| 596 |
's/'. $from .'/'. $to .'/g'; |
| 597 |
} |
| 598 |
} |
| 599 |
|
| 600 |
sub modify_record_regexps { |
| 601 |
my $self = shift; |
| 602 |
my $modify_record = {@_}; |
| 603 |
|
| 604 |
my $regexpes; |
| 605 |
|
| 606 |
my $log = $self->_get_logger(); |
| 607 |
|
| 608 |
foreach my $f (keys %$modify_record) { |
| 609 |
$log->debug("field: $f"); |
| 610 |
|
| 611 |
foreach my $sf (keys %{ $modify_record->{$f} }) { |
| 612 |
$log->debug("subfield: $sf"); |
| 613 |
|
| 614 |
foreach my $from (keys %{ $modify_record->{$f}->{$sf} }) { |
| 615 |
my $to = $modify_record->{$f}->{$sf}->{$from}; |
| 616 |
#die "no field?" unless defined($to); |
| 617 |
my $d = "|$from| -> |$to|"; |
| 618 |
$log->debug("transform: $d"); |
| 619 |
|
| 620 |
my $regex = _get_regex($sf,$from,$to); |
| 621 |
push @{ $regexpes->{$f} }, { regex => $regex, debug => $d }; |
| 622 |
$log->debug("regex: $regex"); |
| 623 |
} |
| 624 |
} |
| 625 |
} |
| 626 |
|
| 627 |
return $regexpes; |
| 628 |
} |
| 629 |
|
| 630 |
=head2 modify_file_regexps |
| 631 |
|
| 632 |
Generate hash with regexpes to be applied using L<filter> from |
| 633 |
pseudo hash/yaml format for regex mappings. |
| 634 |
|
| 635 |
It should be obvious: |
| 636 |
|
| 637 |
200 |
| 638 |
'^a' |
| 639 |
' : ' => '^e' |
| 640 |
' = ' => '^d' |
| 641 |
|
| 642 |
In field I<200> find C<'^a'> and then C<' : '>, and replace it with C<'^e'>. |
| 643 |
In field I<200> find C<'^a'> and then C<' = '>, and replace it with C<'^d'>. |
| 644 |
|
| 645 |
my $regexpes = $input->modify_file_regexps( 'conf/modify/common.pl' ); |
| 646 |
|
| 647 |
On undef path it will just return. |
| 648 |
|
| 649 |
=cut |
| 650 |
|
| 651 |
sub modify_file_regexps { |
| 652 |
my $self = shift; |
| 653 |
|
| 654 |
my $modify_path = shift || return; |
| 655 |
|
| 656 |
my $log = $self->_get_logger(); |
| 657 |
|
| 658 |
my $regexpes; |
| 659 |
|
| 660 |
CORE::open(my $fh, $modify_path) || $log->logdie("can't open modify file $modify_path: $!"); |
| 661 |
|
| 662 |
my ($f,$sf); |
| 663 |
|
| 664 |
while(<$fh>) { |
| 665 |
chomp; |
| 666 |
next if (/^#/ || /^\s*$/); |
| 667 |
|
| 668 |
if (/^\s*(\d+)\s*$/) { |
| 669 |
$f = $1; |
| 670 |
$log->debug("field: $f"); |
| 671 |
next; |
| 672 |
} elsif (/^\s*'([^']*)'\s*$/) { |
| 673 |
$sf = $1; |
| 674 |
$log->die("can't define subfiled before field in: $_") unless ($f); |
| 675 |
$log->debug("subfield: $sf"); |
| 676 |
} elsif (/^\s*'([^']*)'\s*=>\s*'([^']*)'\s*$/) { |
| 677 |
my ($from,$to) = ($1, $2); |
| 678 |
|
| 679 |
$log->debug("transform: |$from| -> |$to|"); |
| 680 |
|
| 681 |
my $regex = _get_regex($sf,$from,$to); |
| 682 |
push @{ $regexpes->{$f} }, { |
| 683 |
regex => $regex, |
| 684 |
file => $modify_path, |
| 685 |
line => $., |
| 686 |
}; |
| 687 |
$log->debug("regex: $regex"); |
| 688 |
} |
| 689 |
} |
| 690 |
|
| 691 |
return $regexpes; |
| 692 |
} |
| 693 |
|
| 694 |
=head1 AUTHOR |
| 695 |
|
| 696 |
Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >> |
| 697 |
|
| 698 |
=head1 COPYRIGHT & LICENSE |
| 699 |
|
| 700 |
Copyright 2005-2006 Dobrica Pavlinusic, All Rights Reserved. |
| 701 |
|
| 702 |
This program is free software; you can redistribute it and/or modify it |
| 703 |
under the same terms as Perl itself. |
| 704 |
|
| 705 |
=cut |
| 706 |
|
| 707 |
1; # End of WebPAC::Input |
Parent Directory
| 
Revision Log